Rotinas LISP para AutoCAD e Civil 3D: como carregá-las sem risco, 3 rotinas úteis e quando passar para um plugin

AutoLISP é uma linguagem que o AutoCAD inclui desde os anos 80. Uma rotina LISP define um ou mais comandos novos que são executados como qualquer comando do AutoCAD.

Onde funciona:

• No AutoCAD e em todas as suas versões verticais, incluindo o Civil 3D.
• No AutoCAD LT para Windows desde a versão 2024. Antes, as versões LT não executavam LISP.

Para que é bom:

• Rotular, numerar, renomear layers, mudar propriedades em lote.
• Medir e somar: comprimentos, áreas, quantidades de blocos.
• Exportar e importar dados simples para arquivos de texto ou CSV.

Onde se escreve: desde o AutoCAD 2021, o editor recomendado é o Visual Studio Code com a extensão de AutoLISP da Autodesk, que substitui o antigo editor Visual LISP.

Para usá-la uma vez:

1. Digite APPLOAD na linha de comando.
2. Procure o arquivo .lsp e clique em Carregar.
3. Digite o comando que a rotina define.

Você também pode arrastar o arquivo .lsp para a janela do desenho.

Para que fique sempre disponível: no mesmo quadro do APPLOAD, adicione a rotina ao Startup Suite (os aplicativos de inicialização). Ela será carregada em cada desenho que você abrir.

Exporta os objetos ponto (POINT) selecionados para um arquivo CSV no formato PNEZD: número, Norte, Este, cota e descrição. Esse arquivo é importado diretamente no Civil 3D como pontos COGO. Como importá-lo sem erros, em importar pontos no Civil 3D.

;; ZPONTOSCSV: exporta os pontos (POINT) selecionados para um CSV PNEZD
(defun c:ZPONTOSCSV (/ ss arq f i n p)
  (setq ss (ssget '((0 . "POINT"))))
  (if ss
    (progn
      (setq arq (getfiled "Salvar pontos" "" "csv" 1))
      (if arq
        (progn
          (setq f (open arq "w") i 0 n 1)
          (repeat (sslength ss)
            (setq p (cdr (assoc 10 (entget (ssname ss i)))))
            (write-line
              (strcat (itoa n) ","
                      (rtos (cadr p) 2 3) ","
                      (rtos (car p) 2 3) ","
                      (rtos (caddr p) 2 3) ",PT")
              f)
            (setq i (1+ i) n (1+ n)))
          (close f)
          (princ (strcat "\n" (itoa (sslength ss)) " pontos exportados para " arq)))))
    (princ "\nNenhum ponto selecionado."))
  (princ))

Como funciona: ssget com o filtro (0 . "POINT") deixa selecionar só pontos; getfiled abre o quadro para salvar; cada linha escreve o Norte (Y) antes do Este (X), que é a ordem do PNEZD.

Pede pontos no desenho e escreve ao lado um texto com seu Este e seu Norte. Serve para plantas de situação, vértices de um terreno ou pontos de controle.

;; ZCOORD: rotula as coordenadas Este e Norte de cada ponto indicado
(defun c:ZCOORD (/ alt p w)
  (setq alt (getreal "\nAltura do texto <2.5>: "))
  (if (not alt) (setq alt 2.5))
  (while (setq p (getpoint "\nPonto a rotular (Enter para terminar): "))
    (setq w (trans p 1 0))
    (entmake
      (list (cons 0 "TEXT")
            (cons 10 w)
            (cons 40 alt)
            (cons 1 (strcat "E " (rtos (car w) 2 3) "  N " (rtos (cadr w) 2 3))))))
  (princ))

Como funciona: getpoint devolve o ponto no sistema de coordenadas do usuário (UCS); trans o converte para o sistema universal (WCS), que é o que guarda as coordenadas reais. Sem esse passo, com um UCS girado, o rótulo mostraria coordenadas erradas.

Soma o comprimento de tudo o que foi selecionado. Útil para levantar tubulações, sarjetas, meios-fios ou qualquer elemento desenhado como linha.

;; ZCOMPTOTAL: soma o comprimento de linhas, polilinhas, arcos, circulos e splines
(vl-load-com)
(defun c:ZCOMPTOTAL (/ ss i total e)
  (setq ss (ssget '((0 . "LINE,LWPOLYLINE,POLYLINE,ARC,CIRCLE,SPLINE")))
        total 0.0
        i 0)
  (if ss
    (progn
      (repeat (sslength ss)
        (setq e (ssname ss i)
              total (+ total (vlax-curve-getDistAtParam e (vlax-curve-getEndParam e)))
              i (1+ i)))
      (princ (strcat "\nObjetos: " (itoa (sslength ss))
                     "   Comprimento total: " (rtos total 2 3))))
    (princ "\nNada selecionado."))
  (princ))

Como funciona: vl-load-com ativa as funções vlax-curve, que medem qualquer curva da mesma forma, seja uma linha, uma polilinha ou um arco.

O AutoCAD carrega automaticamente certos arquivos, como acad.lsp e acaddoc.lsp, se os encontra na pasta do desenho ou nos caminhos de busca. Esse comportamento já foi usado para propagar malware: um arquivo LISP escondido que viaja junto com os desenhos e é executado ao abri-los.

O caso mais conhecido aconteceu na América do Sul. Em 2012, a empresa de segurança ESET documentou o ACAD/Medre.A, um malware escrito em AutoLISP que se propagou sobretudo no Peru e enviou dezenas de milhares de desenhos por e-mail para contas na China.

Como se proteger:

• Mantenha o SECURELOAD em 1 ou 2, nunca em 0.
• Tenha uma única pasta de rotinas revisadas como local confiável.
• Desconfie de um acad.lsp ou acaddoc.lsp que apareça junto com desenhos recebidos de terceiros.
• Não carregue arquivos .fas ou .vlx de origem desconhecida: não podem ser lidos, então você não sabe o que fazem.

O LISP trabalha muito bem com o que o AutoCAD desenha: linhas, polilinhas, textos, blocos e layers. Com os objetos de engenharia do Civil 3D é outra história: ele os vê quase como caixas fechadas. Para ler os dados de um alinhamento, uma superfície ou um corredor, precisa passar pela interface COM do Civil 3D, que é trabalhosa, muda entre versões e não cobre tudo.

Sinais de que sua rotina já deveria ser um plugin:

• Precisa ler ou modificar alinhamentos, perfis, superfícies, corredores ou redes de tubulação.
• Precisa de uma janela com opções, validações ou tabelas, além de perguntas na linha de comando.
• O escritório inteiro a usa e um erro custa horas de trabalho.
• Só uma pessoa a entende.

Se você quer dar o passo sozinho, comece pela API do Civil 3D em C#. Se prefere que nós façamos, explicamos em desenvolvimento de add-ins para Revit e Civil 3D.